home *** CD-ROM | disk | FTP | other *** search
/ Linear Technology Linearview 1996 / linearview 1996.iso / spice / opnom.lib < prev    next >
Encoding:
Text File  |  1996-07-09  |  2.3 KB  |  73 lines
  1. * Library of Op Amp subcircuit definitions
  2. *
  3. * This is a reduced version of MicroSim's opamp subcircuit library.
  4. *   You are welcome to make as many copies of it as you find convenient.
  5. *
  6. * Release date: 87/06/22
  7. *
  8. * The parameters in this opamp library were derived from the data
  9. * sheets for each part.  The macromodel used is described in:
  10. *
  11. *    Macromodeling of Integrated Circuit Operational Amplifiers
  12. *        by Graeme Boyle, Barry Cohn, Donald Pederson, and
  13. *           James Solomon
  14. *    IEEE Journal of Solid-State Circuits, Vol. SC-9, no. 6,    Dec. 1974
  15. *
  16. * Differences from the reference (above) occur in the output limiting stage
  17. * which was modified to reduce internally generated currents associated with
  18. * output voltage limiting, as well as short-circuit current limiting.
  19. *
  20. * The opamps are modelled at room temperature.  The macro model
  21. * does not track changes with temperature.  This library file contains
  22. * models for nominal, not worst case, devices.
  23. *
  24. * Note: Each macromodel consists of a subcircuit definition AND a set
  25. *    of .MODEL statements.  The .MODEL statements should be put into
  26. *    the main circuit file along with the subcircuit definition.
  27. *
  28. *
  29. *-----------------------------------------------------------------------------
  30. * connections:   non-inverting input
  31. *                | inverting input
  32. *                | | positive power supply
  33. *                | | | negative power supply
  34. *                | | | | output
  35. *                | | | | |
  36. .subckt uA741    1 2 3 4 5
  37. *
  38.   c1   11 12 8.661E-12
  39.   c2    6  7 30.00E-12
  40.   dc    5 53 dx
  41.   de   54  5 dx
  42.   dlp  90 91 dx
  43.   dln  92 90 dx
  44.   dp    4  3 dx
  45.   egnd 99  0 poly(2) (3,0) (4,0) 0 .5 .5
  46.   fb    7 99 poly(5) vb vc ve vlp vln 0 10.61E6 -10E6 10E6 10E6 -10E6
  47.   ga    6  0 11 12 188.5E-6
  48.   gcm   0  6 10 99 5.961E-9
  49.   iee  10  4 dc 15.16E-6
  50.   hlim 90  0 vlim 1K
  51.   q1   11  2 13 qx
  52.   q2   12  1 14 qx
  53.   r2    6  9 100.0E3
  54.   rc1   3 11 5.305E3
  55.   rc2   3 12 5.305E3
  56.   re1  13 10 1.836E3
  57.   re2  14 10 1.836E3
  58.   ree  10 99 13.19E6
  59.   ro1   8  5 50
  60.   ro2   7 99 100
  61.   rp    3  4 18.16E3
  62.   vb    9  0 dc 0
  63.   vc    3 53 dc 1
  64.   ve   54  4 dc 1
  65.   vlim  7  8 dc 0
  66.   vlp  91  0 dc 40
  67.   vln   0 92 dc 40
  68. .model dx D(Is=800.0E-18)
  69. .model qx NPN(Is=800.0E-18 Bf=93.75)
  70. .ends
  71. *
  72. * End of library file
  73.